.版本 2
.子程序 取队员名单, 文本型, , 读内存返回当前队员名用斜杠分隔（无队员返回空）
.局部变量 队员对象, 整数型
.局部变量 队员名称, 文本型
.局部变量 队员位置, 整数型
.局部变量 名单, 文本型
.计次循环首 (8, 队员位置)
队员对象 ＝ 内存_读整数型 (全局_进程句柄, #队员基址 ＋ 4 × (队员位置 － 1))
.如果真 (队员对象 ≤ 0)
到循环尾 ()
.如果真结束
队员名称 ＝ 编码_BIG5到简体 (内存_读文本型 (全局_进程句柄, 队员对象 ＋ #队员名称值))
.如果真 (队员名称 ≠ “”)
名单 ＝ 名单 ＋ 队员名称 ＋ “/”
.如果真结束
.计次循环尾 ()
.如果真 (取文本长度 (名单) ＞ 0)
名单 ＝ 取文本左边 (名单, 取文本长度 (名单) － 1)
.如果真结束
返回 (名单)
.版本 2
.子程序 统计队员数, 整数型, , 数斜杠名单里的人数（不含自己）
.参数 名单文本, 文本型
.局部变量 arr, 文本型, , "8"
.局部变量 i, 整数型
.局部变量 数量, 整数型
.如果真 (名单文本 ＝ “”)
返回 (0)
.如果真结束
arr ＝ 分割文本 (名单文本, “/”, )
.计次循环首 (取数组成员数 (arr), i)
.如果真 (arr [i] ≠ “”)
数量 ＝ 数量 ＋ 1
.如果真结束
.计次循环尾 ()
返回 (数量)
.版本 2
.子程序 在名单中, 逻辑型, , 判断一个名字是否在斜杠分隔的名单里
.参数 查找名, 文本型
.参数 名单文本, 文本型
.局部变量 arr, 文本型, , "8"
.局部变量 i, 整数型
.如果真 (名单文本 ＝ “”)
返回 (假)
.如果真结束
arr ＝ 分割文本 (名单文本, “/”, )
.计次循环首 (取数组成员数 (arr), i)
.如果真 (arr [i] ＝ 查找名)
返回 (真)
.如果真结束
.计次循环尾 ()
返回 (假)
.版本 2
.子程序 自动组队邀请, , , 按列表名单逐个邀请（已在队跳过 满员即停 邀请后确认入队）
.局部变量 名单文本, 文本型
.局部变量 名单数组, 文本型, , "8"
.局部变量 n, 整数型
.局部变量 目标值, 整数型
.局部变量 当前队员, 文本型
.局部变量 总人数, 整数型
.局部变量 有效数, 整数型
.局部变量 跳过数, 整数型
名单文本 ＝ 取列表名单文本 ()
.如果真 (名单文本 ＝ “”)
写日志 (自定义时间 () ＋ “列表为空，请先添加名字” ＋ #换行符)
自动组队运行中 ＝ 假
返回 ()
.如果真结束
名单数组 ＝ 分割文本 (名单文本, “/”, )
.计次循环首 (取数组成员数 (名单数组), n)
.如果真 (自动组队停止 ＝ 真)
跳出循环 ()
.如果真结束
.如果真 (名单数组 [n] ≠ “”)
有效数 ＝ 有效数 ＋ 1
当前队员 ＝ 取队员名单 ()
总人数 ＝ 统计队员数 (当前队员) ＋ 1
.如果真 (总人数 ≥ #队伍人数上限)
写日志 (自定义时间 () ＋ “队伍已满员（” ＋ 到文本 (总人数) ＋ “人），停止邀请” ＋ #换行符)
跳出循环 ()
.如果真结束
.如果真 (在名单中 (名单数组 [n], 当前队员))
写日志 (自定义时间 () ＋ “已在队中，跳过：” ＋ 名单数组 [n] ＋ #换行符)
跳过数 ＝ 跳过数 ＋ 1
到循环尾 ()
.如果真结束
目标值 ＝ 取玩家ID (名单数组 [n])
.如果 (目标值 ≠ 0)
发包邀请组队 (目标值)
写日志 (自定义时间 () ＋ “已邀请：” ＋ 名单数组 [n] ＋ “ (目标值:” ＋ 到文本 (目标值) ＋ “)” ＋ #换行符)
.否则
写日志 (自定义时间 () ＋ “未找到：” ＋ 名单数组 [n] ＋ “（使用发包名字组队）” ＋ #换行符)
发包名字组队 (名单数组 [n])
.如果结束
程序_延时 (5000)
.如果真 (自动组队停止 ＝ 真)
跳出循环 ()
.如果真结束
当前队员 ＝ 取队员名单 ()
.如果真 (在名单中 (名单数组 [n], 当前队员))
写日志 (自定义时间 () ＋ “确认入队：” ＋ 名单数组 [n] ＋ #换行符)
.否则
写日志 (自定义时间 () ＋ “5秒后未入队：” ＋ 名单数组 [n] ＋ “（可能对方未接受，继续下一个）” ＋ #换行符)
.如果真结束
.如果真结束
.计次循环尾 ()
.如果真 (有效数 ＞ 0 且 跳过数 ≥ 有效数)
写日志 (自定义时间 () ＋ “名单全部已在队，自动停止组队” ＋ #换行符)
自动组队.选中 ＝ 假
.如果真结束
自动组队运行中 ＝ 假
写日志 (自定义时间 () ＋ “名单邀请执行完毕” ＋ #换行符)
.版本 2
.子程序 遍历队员
.局部变量 队员对象, 整数型
.局部变量 队员序号, 整数型
.局部变量 队员名称, 文本型
.局部变量 队员位置, 整数型
.局部变量 成员数, 整数型
.计次循环首 (8, 队员位置)
队员对象 ＝ 内存_读整数型 (全局_进程句柄, #队员基址 ＋ 4 × (队员位置 － 1))
.如果真 (队员对象 ≤ 0)
到循环尾 ()
.如果真结束
队员名称 ＝ 编码_BIG5到简体 (内存_读文本型 (全局_进程句柄, 队员对象 ＋ #队员名称值))
.如果真 (队员名称 ≠ “”)
队员序号 ＝ 位与 (内存_读整数型 (全局_进程句柄, 队员对象 ＋ #队员序号值), 65535)
挂机信息.加入文本 (自定义时间 () ＋ “*****************” ＋ #换行符)
挂机信息.加入文本 (自定义时间 () ＋ “队员格号：” ＋ 到文本 (队员位置) ＋ #换行符)
挂机信息.加入文本 (自定义时间 () ＋ “队员序号：” ＋ 到文本 (队员序号) ＋ #换行符)
挂机信息.加入文本 (自定义时间 () ＋ “队员名称：” ＋ 队员名称 ＋ #换行符)
成员数 ＝ 成员数 ＋ 1
.如果真结束
.计次循环尾 ()
挂机信息.加入文本 (自定义时间 () ＋ “遍历完成，共 ” ＋ 到文本 (成员数) ＋ “ 人” ＋ #换行符 ＋ #换行符)